nf-core_modules/modules/gatk4/applyvqsr/main.nf

process GATK4_APPLYVQSR {
    tag "$meta.id"
    label 'process_low'

    conda (params.enable_conda ? "bioconda::gatk4=4.2.4.0" : null)
    container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
        'https://depot.galaxyproject.org/singularity/gatk4:4.2.4.0--hdfd78af_0' :
        'quay.io/biocontainers/gatk4:4.2.4.0--hdfd78af_0' }"

    input:
    tuple val(meta), path(vcf), path(tbi), path(recal), path(recalidx), path(tranches)
    path fasta
    path fai
    path dict
    val allelespecific
    val truthsensitivity
    val mode

    output:
    tuple val(meta), path("*.vcf.gz")     , emit: vcf
    tuple val(meta), path("*.tbi")        , emit: tbi
    path "versions.yml"                   , emit: versions

    script:
    def args = task.ext.args ?: ''
    def prefix = task.ext.prefix ?: "${meta.id}"
    refCommand = fasta ? "-R ${fasta} " : ''
    alleleSpecificCommand = allelespecific ? '-AS' : ''
    truthSensitivityCommand = truthsensitivity ? "--truth-sensitivity-filter-level ${truthsensitivity}" : ''
    modeCommand = mode ? "--mode ${mode} " : 'SNP'

    def avail_mem = 3
    if (!task.memory) {
        log.info '[GATK ApplyVQSR] Available memory not known - defaulting to 3GB. Specify process memory requirements to change this.'
    } else {
        avail_mem = task.memory.giga
    }
    """
    gatk --java-options "-Xmx${avail_mem}g" ApplyVQSR \\
        ${refCommand} \\
        -V ${vcf} \\
        -O ${prefix}.vcf.gz \\
        ${alleleSpecificCommand} \\
        ${truthSensitivityCommand} \\
        --tranches-file $tranches \\
        --recal-file $recal \\
        ${modeCommand} \\
        $args

    cat <<-END_VERSIONS > versions.yml
    "${task.process}":
        gatk4: \$(echo \$(gatk --version 2>&1) | sed 's/^.*(GATK) v//; s/ .*\$//')
    END_VERSIONS
    """
}