Add bcftools/norm module (#655)

* Initial draft [ci skip]

* trigger first test

* update output file path

* Tests passing

* finishing touches for meta.yml and update checksum

* tweak checksum

* add threads to the module

* skip version info for matching test md5sum [ci skip]

* Add ref fasta and finalize the module

Co-authored-by: Gregor Sturm <mail@gregor-sturm.de>

modules/bcftools/norm/functions.nf

@@ -0,0 +1,68 @@
+//
+//  Utility functions used in nf-core DSL2 module files
+//
+
+//
+// Extract name of software tool from process name using $task.process
+//
+def getSoftwareName(task_process) {
+    return task_process.tokenize(':')[-1].tokenize('_')[0].toLowerCase()
+}
+
+//
+// Function to initialise default values and to generate a Groovy Map of available options for nf-core modules
+//
+def initOptions(Map args) {
+    def Map options = [:]
+    options.args            = args.args ?: ''
+    options.args2           = args.args2 ?: ''
+    options.args3           = args.args3 ?: ''
+    options.publish_by_meta = args.publish_by_meta ?: []
+    options.publish_dir     = args.publish_dir ?: ''
+    options.publish_files   = args.publish_files
+    options.suffix          = args.suffix ?: ''
+    return options
+}
+
+//
+// Tidy up and join elements of a list to return a path string
+//
+def getPathFromList(path_list) {
+    def paths = path_list.findAll { item -> !item?.trim().isEmpty() }      // Remove empty entries
+    paths     = paths.collect { it.trim().replaceAll("^[/]+|[/]+\$", "") } // Trim whitespace and trailing slashes
+    return paths.join('/')
+}
+
+//
+// Function to save/publish module results
+//
+def saveFiles(Map args) {
+    if (!args.filename.endsWith('.version.txt')) {
+        def ioptions  = initOptions(args.options)
+        def path_list = [ ioptions.publish_dir ?: args.publish_dir ]
+        if (ioptions.publish_by_meta) {
+            def key_list = ioptions.publish_by_meta instanceof List ? ioptions.publish_by_meta : args.publish_by_meta
+            for (key in key_list) {
+                if (args.meta && key instanceof String) {
+                    def path = key
+                    if (args.meta.containsKey(key)) {
+                        path = args.meta[key] instanceof Boolean ? "${key}_${args.meta[key]}".toString() : args.meta[key]
+                    }
+                    path = path instanceof String ? path : ''
+                    path_list.add(path)
+                }
+            }
+        }
+        if (ioptions.publish_files instanceof Map) {
+            for (ext in ioptions.publish_files) {
+                if (args.filename.endsWith(ext.key)) {
+                    def ext_list = path_list.collect()
+                    ext_list.add(ext.value)
+                    return "${getPathFromList(ext_list)}/$args.filename"
+                }
+            }
+        } else if (ioptions.publish_files == null) {
+            return "${getPathFromList(path_list)}/$args.filename"
+        }
+    }
+}

modules/bcftools/norm/main.nf

@@ -0,0 +1,42 @@
+// Import generic module functions
+include { initOptions; saveFiles; getSoftwareName } from './functions'
+
+params.options = [:]
+options        = initOptions(params.options)
+
+process BCFTOOLS_NORM {
+    tag "$meta.id"
+    label 'process_medium'
+    publishDir "${params.outdir}",
+        mode: params.publish_dir_mode,
+        saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), meta:meta, publish_by_meta:['id']) }
+
+    conda (params.enable_conda ? "bioconda::bcftools=1.13" : null)
+    if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
+        container "https://depot.galaxyproject.org/singularity/bcftools:1.13--h3a49de5_0"
+    } else {
+        container "quay.io/biocontainers/bcftools:1.13--h3a49de5_0"
+    }
+
+    input:
+    tuple val(meta), path(vcf)
+    path(fasta)
+
+    output:
+    tuple val(meta), path("*.gz") , emit: vcf
+    path "*.version.txt"          , emit: version
+
+    script:
+    def software = getSoftwareName(task.process)
+    def prefix   = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
+    """
+    bcftools norm \\
+        --fasta-ref ${fasta} \\
+        --output ${prefix}.vcf.gz \\
+        $options.args \\
+        --threads $task.cpus \\
+        ${vcf}
+
+    echo \$(bcftools --version 2>&1) | sed 's/^.*bcftools //; s/ .*\$//' > ${software}.version.txt
+    """
+}

modules/bcftools/norm/meta.yml

@@ -0,0 +1,45 @@
+name: bcftools_norm
+description: Normalize VCF file
+keywords:
+  - normalize
+  - norm
+  - variant calling
+  - VCF
+tools:
+    - norm:
+        description: |
+          Normalize VCF files.
+        homepage: http://samtools.github.io/bcftools/bcftools.html
+        documentation: http://www.htslib.org/doc/bcftools.html
+        doi: 10.1093/bioinformatics/btp352
+input:
+    - meta:
+        type: map
+        description: |
+          Groovy Map containing sample information
+          e.g. [ id:'test', single_end:false ]
+    - vcf:
+        type: file
+        description: |
+          The vcf file to be normalized
+          e.g. 'file1.vcf'
+    - fasta:
+        type: file
+        description: FASTA reference file
+        pattern: "*.{fasta,fa}"
+output:
+    - meta:
+        type: map
+        description: |
+          Groovy Map containing sample information
+          e.g. [ id:'test', single_end:false ]
+    - vcf:
+        type: file
+        description: VCF normalized output file
+        pattern: "*.{vcf.gz}"
+    - version:
+        type: file
+        description: File containing software version
+        pattern: "*.{version.txt}"
+authors:
+    - "@abhi18av"

tests/config/pytest_modules.yml

@@ -54,6 +54,10 @@ bcftools/mpileup:
   - modules/bcftools/mpileup/**
   - tests/modules/bcftools/mpileup/**
 
+bcftools/norm:
+  - modules/bcftools/norm/**
+  - tests/modules/bcftools/norm/**
+
 bcftools/reheader:
   - modules/bcftools/reheader/**
   - tests/modules/bcftools/reheader/**

tests/modules/bcftools/norm/main.nf

@@ -0,0 +1,15 @@
+#!/usr/bin/env nextflow
+
+nextflow.enable.dsl = 2
+
+include { BCFTOOLS_NORM } from '../../../../modules/bcftools/norm/main.nf' addParams( options: ['args': '-m -any --no-version'] )
+
+workflow test_bcftools_norm {
+    
+    input = [ [ id:'test2', single_end:false ], // meta map
+              file(params.test_data['sarscov2']['illumina']['test_vcf_gz'], checkIfExists: true)]
+
+    fasta = file(params.test_data['sarscov2']['genome']['genome_fasta'], checkIfExists: true)
+
+    BCFTOOLS_NORM ( input, fasta )
+}

tests/modules/bcftools/norm/test.yml

@@ -0,0 +1,8 @@
+- name: bcftools norm
+  command: nextflow run ./tests/modules/bcftools/norm -entry test_bcftools_norm -c tests/config/nextflow.config
+  tags:
+    - bcftools
+    - bcftools/norm
+  files:
+    - path: output/bcftools/test2.vcf.gz
+      md5sum: 2b1cac07d1875b8adcd7a85346890f07