Merge pull request #1616 from jianhong/motus_profile

Motus profile

modules/motus/profile/main.nf

@@ -0,0 +1,54 @@
+process MOTUS_PROFILE {
+    tag "$meta.id"
+    label 'process_medium'
+
+    conda (params.enable_conda ? "bioconda::motus=3.0.1" : null)
+    container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
+        'https://depot.galaxyproject.org/singularity/motus:3.0.1--pyhdfd78af_0':
+        'quay.io/biocontainers/motus:3.0.1--pyhdfd78af_0' }"
+
+    input:
+    tuple val(meta), path(reads)
+    path db
+
+    output:
+    tuple val(meta), path("*.out"), emit: out
+    tuple val(meta), path("*.bam"), optional: true, emit: bam
+    tuple val(meta), path("*.mgc"), optional: true, emit: mgc
+    path "versions.yml"           , emit: versions
+
+    when:
+    task.ext.when == null || task.ext.when
+
+    script:
+    def args = task.ext.args ?: ''
+    def prefix = task.ext.prefix ?: "${meta.id}"
+    def inputs = reads[0].getExtension() == 'bam' ?
+                    "-i ${reads}" :
+                    reads[0].getExtension() == 'mgc' ? "-m $reads" :
+                        meta.single_end ?
+                            "-s $reads" : "-f ${reads[0]} -r ${reads[1]}"
+    def refdb = db ? "-db ${db}" : ""
+    """
+    motus profile \\
+        $args \\
+        $inputs \\
+        $refdb \\
+        -t $task.cpus \\
+        -n $prefix \\
+        -o ${prefix}.out
+
+    ## mOTUs version number is not available from command line.
+    ## mOTUs save the version number in index database folder.
+    ## mOTUs will check the database version is same version as exec version.
+    if [ "$db" == "" ]; then
+        VERSION=\$(echo \$(motus -h 2>&1) | sed 's/^.*Version: //; s/References.*\$//')
+    else
+        VERSION=\$(grep motus $db/db_mOTU_versions | sed 's/motus\\t//g')
+    fi
+    cat <<-END_VERSIONS > versions.yml
+    "${task.process}":
+        mOTUs: \$VERSION
+    END_VERSIONS
+    """
+}

modules/motus/profile/meta.yml

@@ -0,0 +1,61 @@
+name: "motus_profile"
+description: Taxonomic meta-omics profiling using universal marker genes
+keywords:
+  - classify
+  - metagenomics
+  - fastq
+  - taxonomic profiling
+tools:
+  - "motus":
+      description: "Marker gene-based OTU (mOTU) profiling"
+      homepage: "https://motu-tool.org/"
+      documentation: "https://github.com/motu-tool/mOTUs/wiki"
+      tool_dev_url: "https://github.com/motu-tool/mOTUs"
+      doi: "10.1038/s41467-019-08844-4"
+      licence: "['GPL v3']"
+
+input:
+  - meta:
+      type: map
+      description: |
+        Groovy Map containing sample information
+        e.g. [ id:'test', single_end:false ]
+  - reads:
+      type: file
+      description: |
+        List of input fastq/fasta files of size 1 and 2 for single-end and paired-end data,
+        respectively.
+        Or the intermediate bam file mapped by bwa to the mOTUs database or
+        the output bam file from motus profile.
+        Or the intermediate mgc read counts table.
+      pattern: "*.{fastq,fq,fasta,fa,fastq.gz,fq.gz,fasta.gz,fa.gz,.bam,.mgc}"
+  - db:
+      type: directory
+      description: |
+        mOTUs database downloaded by `motus downloadDB`
+
+output:
+  - meta:
+      type: map
+      description: |
+        Groovy Map containing sample information
+        e.g. [ id:'test', single_end:false ]
+  - versions:
+      type: file
+      description: File containing software versions
+      pattern: "versions.yml"
+  - out:
+      type: file
+      description: Results with taxonomic classification of each read
+      pattern: "*.out"
+  - bam:
+      type: file
+      description: Optional intermediate sorted BAM file from BWA
+      pattern: "*.{bam}"
+  - mgc:
+      type: file
+      description: Optional intermediate mgc read count table file saved with `-M`.
+      pattern: "*.{mgc}"
+
+authors:
+  - "@jianhong"

tests/config/pytest_modules.yml

@@ -1310,6 +1310,10 @@ motus/downloaddb:
   - modules/motus/downloaddb/**
   - tests/modules/motus/downloaddb/**
 
+motus/profile:
+  - modules/motus/profile/**
+  - tests/modules/motus/profile/**
+
 msisensor/msi:
   - modules/msisensor/msi/**
   - tests/modules/msisensor/msi/**

tests/modules/motus/profile/main.nf

@@ -0,0 +1,19 @@
+#!/usr/bin/env nextflow
+
+nextflow.enable.dsl = 2
+
+include { MOTUS_DOWNLOADDB } from '../../../../modules/motus/downloaddb/main.nf'
+include { MOTUS_PROFILE    } from '../../../../modules/motus/profile/main.nf'
+
+workflow test_motus_profile_single_end {
+
+    input = [
+        [ id:'test', single_end:true ], // meta map
+        file(params.test_data['sarscov2']['illumina']['test_1_fastq_gz'], checkIfExists: true)
+    ]
+
+    MOTUS_DOWNLOADDB(file('https://raw.githubusercontent.com/motu-tool/mOTUs/master/motus/downloadDB.py'))
+
+    MOTUS_PROFILE ( input,  MOTUS_DOWNLOADDB.out.db )
+}
+

tests/modules/motus/profile/nextflow.config

@@ -0,0 +1,5 @@
+process {
+
+    publishDir = { "${params.outdir}/${task.process.tokenize(':')[-1].tokenize('_')[0].toLowerCase()}" }
+    
+}

tests/modules/motus/profile/test.yml

@@ -0,0 +1,8 @@
+- name: motus profile test_motus_profile_single_end
+  command: nextflow run tests/modules/motus/profile -entry test_motus_profile_single_end -c tests/config/nextflow.config
+  tags:
+    - motus
+    - motus/profile
+  files:
+    - path: output/motus/test.out
+      contains: ["#consensus_taxonomy\ttest"]