diff --git a/modules/vardictjava/main.nf b/modules/vardictjava/main.nf
new file mode 100644
index 00000000..454b86a4
--- /dev/null
+++ b/modules/vardictjava/main.nf
@@ -0,0 +1,50 @@
+def VERSION = '1.8.3'
+
+process VARDICTJAVA {
+    tag "$meta.id"
+    label 'process_medium'
+
+    conda (params.enable_conda ? "bioconda::vardict-java=1.8.3" : null)
+    container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
+        'https://depot.galaxyproject.org/singularity/vardict-java:1.8.3--hdfd78af_0':
+        'quay.io/biocontainers/vardict-java:1.8.3--hdfd78af_0' }"
+
+    input:
+    tuple val(meta), path(bam), path(bai)
+    path(bed)
+    tuple path(fasta), path(fasta_fai)
+
+    output:
+    tuple val(meta), path("*.vcf.gz"), emit: vcf
+    path "versions.yml"              , emit: versions
+
+    when:
+    task.ext.when == null || task.ext.when
+
+    script:
+    def args = task.ext.args ?: ''
+    def args2 = task.ext.args2 ?: ''
+    def prefix = task.ext.prefix ?: "${meta.id}"
+
+    """
+    vardict-java \\
+        $args \\
+        -c 1 -S 2 -E 3 \\
+        -b $bam \\
+        -th $task.cpus \\
+        -N $prefix \\
+        -G $fasta \\
+        $bed \\
+        | teststrandbias.R \\
+        | var2vcf_valid.pl \\
+            $args2 \\
+            -N $prefix \\
+        | gzip -c > ${prefix}.vcf.gz
+
+    cat <<-END_VERSIONS > versions.yml
+    "${task.process}":
+        vardict-java: $VERSION
+        var2vcf_valid.pl: \$(echo \$(var2vcf_valid.pl -h | sed -n 2p | awk '{ print \$2 }'))
+    END_VERSIONS
+    """
+}
diff --git a/modules/vardictjava/meta.yml b/modules/vardictjava/meta.yml
new file mode 100644
index 00000000..59fba966
--- /dev/null
+++ b/modules/vardictjava/meta.yml
@@ -0,0 +1,60 @@
+name: "vardictjava"
+
+description: The Java port of the VarDict variant caller
+keywords:
+  - variant calling
+  - VarDict
+  - AstraZeneca
+tools:
+  - "vardictjava":
+      description: "Java port of the VarDict variant discovery program"
+      homepage: "https://github.com/AstraZeneca-NGS/VarDictJava"
+      documentation: "https://github.com/AstraZeneca-NGS/VarDictJava"
+      tool_dev_url: "https://github.com/AstraZeneca-NGS/VarDictJava"
+      doi: "10.1093/nar/gkw227 "
+      licence: "['MIT']"
+
+input:
+  - meta:
+      type: map
+      description: |
+        Groovy Map containing sample information
+        e.g. [ id:'test', single_end:false ]
+  - bam:
+      type: file
+      description: BAM/SAM file
+      pattern: "*.{bam,sam}"
+  - bai:
+      type: file
+      description: Index of the BAM file
+      pattern: "*.bai"
+  - fasta:
+      type: file
+      description: FASTA of the reference genome
+      pattern: "*.{fa,fasta}"
+  - fasta_fai:
+      type: file
+      description: The index of the FASTA of the reference genome
+      pattern: "*.fai"
+  - bed:
+      type: file
+      description: BED with the regions of interest
+      pattern: "*.bed"
+
+output:
+  - meta:
+      type: map
+      description: |
+        Groovy Map containing sample information
+        e.g. [ id:'test', single_end:false ]
+  - versions:
+      type: file
+      description: File containing software versions
+      pattern: "versions.yml"
+  - vcf:
+      type: file
+      description: VCF file output
+      pattern: "*.vcf.gz"
+
+authors:
+  - "@nvnieuwk"
diff --git a/tests/config/pytest_modules.yml b/tests/config/pytest_modules.yml
index 924447d3..e966f18a 100644
--- a/tests/config/pytest_modules.yml
+++ b/tests/config/pytest_modules.yml
@@ -1920,6 +1920,10 @@ unzip:
   - modules/unzip/**
   - tests/modules/unzip/**
 
+vardictjava:
+  - modules/vardictjava/**
+  - tests/modules/vardictjava/**
+
 variantbam:
   - modules/variantbam/**
   - tests/modules/variantbam/**
diff --git a/tests/modules/vardictjava/main.nf b/tests/modules/vardictjava/main.nf
new file mode 100644
index 00000000..d392358a
--- /dev/null
+++ b/tests/modules/vardictjava/main.nf
@@ -0,0 +1,23 @@
+#!/usr/bin/env nextflow
+
+nextflow.enable.dsl = 2
+
+include { VARDICTJAVA } from '../../../modules/vardictjava/main.nf'
+
+workflow test_vardictjava {
+    
+    bam_input_ch = Channel.value([
+        [ id:'test' ], // meta map
+        file(params.test_data['homo_sapiens']['illumina']['test_paired_end_sorted_bam'], checkIfExists: true),
+        file(params.test_data['homo_sapiens']['illumina']['test_paired_end_sorted_bam_bai'], checkIfExists: true)
+    ])
+
+    bed = Channel.value(file(params.test_data['homo_sapiens']['genome']['genome_bed'], checkIfExists: true))
+
+    reference = Channel.value([
+        file(params.test_data['homo_sapiens']['genome']['genome_fasta'], checkIfExists: true),
+        file(params.test_data['homo_sapiens']['genome']['genome_fasta_fai'], checkIfExists: true)
+    ])
+
+    VARDICTJAVA ( bam_input_ch, bed, reference )
+}
diff --git a/tests/modules/vardictjava/nextflow.config b/tests/modules/vardictjava/nextflow.config
new file mode 100644
index 00000000..50f50a7a
--- /dev/null
+++ b/tests/modules/vardictjava/nextflow.config
@@ -0,0 +1,5 @@
+process {
+
+    publishDir = { "${params.outdir}/${task.process.tokenize(':')[-1].tokenize('_')[0].toLowerCase()}" }
+    
+}
\ No newline at end of file
diff --git a/tests/modules/vardictjava/test.yml b/tests/modules/vardictjava/test.yml
new file mode 100644
index 00000000..8cb29c4e
--- /dev/null
+++ b/tests/modules/vardictjava/test.yml
@@ -0,0 +1,9 @@
+- name: vardictjava test_vardictjava
+  command: nextflow run tests/modules/vardictjava -entry test_vardictjava -c tests/config/nextflow.config
+  tags:
+    - vardictjava
+  files:
+    - path: output/vardictjava/test.vcf.gz
+      md5sum: 3f1f227afc532bddeb58f16fd3013fc8
+    - path: output/vardictjava/versions.yml
+      md5sum: 9b62c431a4f2680412b61c7071bdb1cd