PR for lofreq/indelqual module (#539)

* first commit

* edited functions.nf

* edited functions.nf

* version line updated

* Update software/lofreq/indelqual/main.nf

Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com>

* Update software/lofreq/indelqual/main.nf

Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com>

* Update software/lofreq/indelqual/main.nf

Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com>

* Update software/lofreq/indelqual/meta.yml

Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com>

* Update tests/software/lofreq/indelqual/test.yml

Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com>

* Update tests/software/lofreq/indelqual/main.nf

Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com>

* updated files

* updated file

Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com>

software/lofreq/indelqual/functions.nf

@@ -0,0 +1,68 @@
+//
+//  Utility functions used in nf-core DSL2 module files
+//
+
+//
+// Extract name of software tool from process name using $task.process
+//
+def getSoftwareName(task_process) {
+    return task_process.tokenize(':')[-1].tokenize('_')[0].toLowerCase()
+}
+
+//
+// Function to initialise default values and to generate a Groovy Map of available options for nf-core modules
+//
+def initOptions(Map args) {
+    def Map options = [:]
+    options.args            = args.args ?: ''
+    options.args2           = args.args2 ?: ''
+    options.args3           = args.args3 ?: ''
+    options.publish_by_meta = args.publish_by_meta ?: []
+    options.publish_dir     = args.publish_dir ?: ''
+    options.publish_files   = args.publish_files
+    options.suffix          = args.suffix ?: ''
+    return options
+}
+
+//
+// Tidy up and join elements of a list to return a path string
+//
+def getPathFromList(path_list) {
+    def paths = path_list.findAll { item -> !item?.trim().isEmpty() }      // Remove empty entries
+    paths     = paths.collect { it.trim().replaceAll("^[/]+|[/]+\$", "") } // Trim whitespace and trailing slashes
+    return paths.join('/')
+}
+
+//
+// Function to save/publish module results
+//
+def saveFiles(Map args) {
+    if (!args.filename.endsWith('.version.txt')) {
+        def ioptions  = initOptions(args.options)
+        def path_list = [ ioptions.publish_dir ?: args.publish_dir ]
+        if (ioptions.publish_by_meta) {
+            def key_list = ioptions.publish_by_meta instanceof List ? ioptions.publish_by_meta : args.publish_by_meta
+            for (key in key_list) {
+                if (args.meta && key instanceof String) {
+                    def path = key
+                    if (args.meta.containsKey(key)) {
+                        path = args.meta[key] instanceof Boolean ? "${key}_${args.meta[key]}".toString() : args.meta[key]
+                    }
+                    path = path instanceof String ? path : ''
+                    path_list.add(path)
+                }
+            }
+        }
+        if (ioptions.publish_files instanceof Map) {
+            for (ext in ioptions.publish_files) {
+                if (args.filename.endsWith(ext.key)) {
+                    def ext_list = path_list.collect()
+                    ext_list.add(ext.value)
+                    return "${getPathFromList(ext_list)}/$args.filename"
+                }
+            }
+        } else if (ioptions.publish_files == null) {
+            return "${getPathFromList(path_list)}/$args.filename"
+        }
+    }
+}

software/lofreq/indelqual/main.nf

@@ -0,0 +1,40 @@
+include { initOptions; saveFiles; getSoftwareName } from './functions'
+
+params.options = [:]
+options        = initOptions(params.options)
+
+process LOFREQ_INDELQUAL {
+    tag "$meta.id"
+    label 'process_low'
+    publishDir "${params.outdir}",
+        mode: params.publish_dir_mode,
+        saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), meta:meta, publish_by_meta:['id']) }
+
+    conda (params.enable_conda ? "bioconda::lofreq=2.1.5" : null)
+    if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
+        container "https://depot.galaxyproject.org/singularity/lofreq:2.1.5--py38h588ecb2_4"
+    } else {
+        container "quay.io/biocontainers/lofreq:2.1.5--py38h588ecb2_4"
+    }
+
+    input:
+    tuple val(meta), path(bam)
+    path fasta
+
+    output:
+    tuple val(meta), path("*.bam"), emit: bam
+    path "*.version.txt"          , emit: version
+
+    script:
+    def software = getSoftwareName(task.process)
+    def prefix   = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
+    """
+    lofreq indelqual \\
+        $options.args \\
+        -f $fasta \\
+        -o ${prefix}.bam \\
+        $bam
+
+    echo \$(lofreq version 2>&1) | sed 's/^.*lofreq //; s/Using.*\$//' > ${software}.version.txt
+    """
+}

software/lofreq/indelqual/meta.yml

@@ -0,0 +1,44 @@
+name: lofreq_indelqual
+description: Inserts indel qualities in a BAM file
+keywords:
+  - bam
+  - indel
+  - qualities
+tools:
+  - lofreq:
+      description: Lofreq is a fast and sensitive variant-caller for inferring SNVs and indels from next-generation sequencing data. It's indelqual programme inserts indel qualities in a BAM file
+      homepage: https://csb5.github.io/lofreq/
+      doi: "10.1093/nar/gks918"
+      licence: ['MIT']
+
+input:
+  - meta:
+      type: map
+      description: |
+        Groovy Map containing sample information
+        e.g. [ id:'test', single_end:false ]
+  - bam:
+      type: file
+      description: BAM file
+      pattern: "*.{bam}"
+  - fasta:
+      type: file
+      description: Reference genome FASTA file
+      pattern: "*.{fasta}"
+output:
+  - meta:
+      type: map
+      description: |
+        Groovy Map containing sample information
+        e.g. [ id:'test', single_end:false ]
+  - version:
+      type: file
+      description: File containing software version
+      pattern: "*.{version.txt}"
+  - bam:
+      type: file
+      description: BAM file with indel qualities inserted into it
+      pattern: "*.{bam}"
+
+authors:
+  - "@kaurravneet4123"

tests/config/pytest_software.yml

@@ -422,6 +422,10 @@ last/train:
   - software/last/train/**
   - tests/software/last/train/**
 
+lofreq/indelqual:
+  - software/lofreq/indelqual/**
+  - tests/software/lofreq/indelqual/**
+
 mash/sketch:
   - software/mash/sketch/**
   - tests/software/mash/sketch/**

tests/software/lofreq/indelqual/main.nf

@@ -0,0 +1,16 @@
+#!/usr/bin/env nextflow
+
+nextflow.enable.dsl = 2
+
+
+include { LOFREQ_INDELQUAL } from '../../../../software/lofreq/indelqual/main.nf' addParams( options: [ 'args': '--dindel', 'suffix':'.indelqual'] )
+
+workflow test_lofreq_indelqual {
+    
+    input = [ [ id:'test' ], // meta map
+              file(params.test_data['sarscov2']['illumina']['test_paired_end_bam'], checkIfExists: true) ]
+
+    fasta = file(params.test_data['sarscov2']['genome']['genome_fasta'], checkIfExists: true)
+
+    LOFREQ_INDELQUAL ( input, fasta )
+}

tests/software/lofreq/indelqual/test.yml

@@ -0,0 +1,8 @@
+- name: lofreq indelqual
+  command: nextflow run ./tests/software/lofreq/indelqual -entry test_lofreq_indelqual -c tests/config/nextflow.config
+  tags:
+    - lofreq
+    - lofreq/indelqual
+  files:
+    - path: output/lofreq/test.indelqual.bam
+      md5sum: 18de975638c2633069bfe1a41ebc5ff7