Add minimap2 align module

.github/filters.yml

@@ -48,6 +48,10 @@ gffread:
   - software/gffread/**
   - tests/software/gffread/**
 
+minimap2_align:
+  - software/minimap2/align/**
+  - tests/software/minimap2/align/**
+
 multiqc:
   - software/fastqc/**
   - software/multiqc/**

software/minimap2/align/functions.nf

@@ -0,0 +1,59 @@
+/*
+ * -----------------------------------------------------
+ *  Utility functions used in nf-core DSL2 module files
+ * -----------------------------------------------------
+ */
+
+/*
+ * Extract name of software tool from process name using $task.process
+ */
+def getSoftwareName(task_process) {
+    return task_process.tokenize(':')[-1].tokenize('_')[0].toLowerCase()
+}
+
+/*
+ * Function to initialise default values and to generate a Groovy Map of available options for nf-core modules
+ */
+def initOptions(Map args) {
+    def Map options = [:]
+    options.args          = args.args ?: ''
+    options.args2         = args.args2 ?: ''
+    options.publish_by_id = args.publish_by_id ?: false
+    options.publish_dir   = args.publish_dir ?: ''
+    options.publish_files = args.publish_files
+    options.suffix        = args.suffix ?: ''
+    return options
+}
+
+/*
+ * Tidy up and join elements of a list to return a path string
+ */
+def getPathFromList(path_list) {
+    def paths = path_list.findAll { item -> !item?.trim().isEmpty() }  // Remove empty entries
+    paths = paths.collect { it.trim().replaceAll("^[/]+|[/]+\$", "") } // Trim whitespace and trailing slashes
+    return paths.join('/')
+}
+
+/*
+ * Function to save/publish module results
+ */
+def saveFiles(Map args) {
+    if (!args.filename.endsWith('.version.txt')) {
+        def ioptions = initOptions(args.options)
+        def path_list = [ ioptions.publish_dir ?: args.publish_dir ]
+        if (ioptions.publish_by_id) {
+            path_list.add(args.publish_id)
+        }
+        if (ioptions.publish_files instanceof Map) {
+            for (ext in ioptions.publish_files) {
+                if (args.filename.endsWith(ext.key)) {
+                    def ext_list = path_list.collect()
+                    ext_list.add(ext.value)
+                    return "${getPathFromList(ext_list)}/$args.filename"
+                }
+            }
+        } else if (ioptions.publish_files == null) {
+            return "${getPathFromList(path_list)}/$args.filename"
+        }
+    }
+}

software/minimap2/align/main.nf

@@ -0,0 +1,57 @@
+// Import generic module functions
+include { initOptions; saveFiles; getSoftwareName } from './functions'
+
+params.options = [:]
+def options    = initOptions(params.options)
+
+process MINIMAP2_ALIGN {
+    tag "$meta.id"
+    label 'process_medium'
+    publishDir "${params.outdir}",
+        mode: params.publish_dir_mode,
+        saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), publish_id:meta.id) }
+
+    conda (params.enable_conda ? "bioconda::minimap2=2.17=hed695b0_3" : null)
+
+    if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
+        container "https://depot.galaxyproject.org/singularity/minimap2:2.17--hed695b0_3"
+    } else {
+        container "quay.io/biocontainers/minimap2:2.17--hed695b0_3"
+    }
+
+    input:
+    tuple val(meta), path(reads)
+    path reference
+
+    output:
+    tuple val(meta), path("*.paf"), emit: paf
+    path "*.version.txt"          , emit: version
+
+    script:
+    def software = getSoftwareName(task.process)
+    def prefix   = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
+    if (meta.single_end) {
+        """
+        minimap2 \\
+            $options.args \\
+            -t $task.cpus \\
+            $reference \\
+            $reads \\
+            > ${prefix}.paf
+
+        echo \$(minimap2 --version 2>&1) > ${software}.version.txt
+        """
+    } else {
+        """
+        minimap2 \\
+            $options.args \\
+            -t $task.cpus \\
+            $reference \\
+            ${reads[0]} \\
+            ${reads[1]} \\
+            > ${prefix}.paf
+
+        echo \$(minimap2 --version 2>&1) > ${software}.version.txt
+        """
+    }
+}

software/minimap2/align/meta.yml

@@ -0,0 +1,67 @@
+name: minimap2_align
+description: A versatile pairwise aligner for genomic and spliced nucleotide sequences
+keywords:
+    - align
+    - fasta
+    - fastq
+    - genome
+    - paf
+    - reference
+tools:
+    - minimap2:
+        description: |
+            A versatile pairwise aligner for genomic and spliced nucleotide sequences.
+        homepage: https://github.com/lh3/minimap2
+        documentation: https://github.com/lh3/minimap2#uguide
+params:
+    - outdir:
+        type: string
+        description: |
+            The pipeline's output directory. By default, the module will
+            output files into `$params.outdir/<SOFTWARE>`
+    - publish_dir_mode:
+        type: string
+        description: |
+            Value for the Nextflow `publishDir` mode parameter.
+            Available: symlink, rellink, link, copy, copyNoFollow, move.
+    - enable_conda:
+        type: boolean
+        description: |
+            Run the module with Conda using the software specified
+            via the `conda` directive
+    - singularity_pull_docker_container:
+        type: boolean
+        description: |
+            Instead of directly downloading Singularity images for use with Singularity,
+            force the workflow to pull and convert Docker containers instead.
+input:
+    - meta:
+        type: map
+        description: |
+            Groovy Map containing sample information
+            e.g. [ id:'test', single_end:false ]
+    - reads:
+        type: file
+        description: |
+            List of input FastQ files of size 1 and 2 for single-end and paired-end data,
+            respectively.
+    - reference:
+        type: file
+        description: |
+            Reference database in FASTA format.
+output:
+    - meta:
+        type: map
+        description: |
+            Groovy Map containing sample information
+            e.g. [ id:'test', single_end:false ]
+    - paf:
+        type: file
+        description: Alignment in PAF format
+        pattern: "*.paf"
+    - version:
+        type: file
+        description: File containing software version
+        pattern: "*.{version.txt}"
+authors:
+    - "@heuermh"

tests/software/minimap2/align/main.nf

@@ -0,0 +1,37 @@
+#!/usr/bin/env nextflow
+
+nextflow.enable.dsl = 2
+
+include { MINIMAP2_ALIGN } from '../../../../software/minimap2/align/main.nf' addParams( options: [:] )
+
+workflow test_minimap2_align_single_end {
+
+    def fasta = file("${launchDir}/tests/data/fasta/E_coli/NC_010473.fa", checkIfExists: true)
+
+    def input = []
+    input = [ [ id:'test', single_end:true ], // meta map
+              [ file("${launchDir}/tests/data/fastq/rna/test_R1.fastq.gz", checkIfExists: true) ] ]
+    MINIMAP2_ALIGN ( input, fasta )
+}
+
+workflow test_minimap2_align_paired_end {
+    
+    def fasta = file("${launchDir}/tests/data/fasta/E_coli/NC_010473.fa", checkIfExists: true)
+
+    def input = []
+    input = [ [ id:'test', single_end:false ], // meta map
+              [ file("${launchDir}/tests/data/fastq/rna/test_R1.fastq.gz", checkIfExists: true),
+                file("${launchDir}/tests/data/fastq/rna/test_R2.fastq.gz", checkIfExists: true) ] ]
+    MINIMAP2_ALIGN ( input, fasta )
+}
+
+workflow test_minimap2_align_pairwise {
+    
+    def fasta = file("${launchDir}/tests/data/fasta/E_coli/NC_010473.fa", checkIfExists: true)
+
+    def input = []
+    input = [ [ id:'test', single_end:false ], // meta map
+              [ fasta ] ]
+
+    MINIMAP2_ALIGN ( input, fasta )
+}

tests/software/minimap2/align/test.yml

@@ -0,0 +1,28 @@
+- name: minimap2 align single-end
+  command: nextflow run ./tests/software/minimap2/align -entry test_minimap2_align_single_end -c tests/config/nextflow.config
+  tags:
+    - minimap2
+    - minimap2_align
+    - minimap2_align_single_end
+  files:
+    - path: output/minimap2/test.paf
+      md5: f92567a67adb0563bd6ff9ed97877be9
+
+- name: minimap2 align paired-end
+  command: nextflow run ./tests/software/minimap2/align -entry test_minimap2_align_paired_end -c tests/config/nextflow.config
+  tags:
+    - minimap2
+    - minimap2_align
+    - minimap2_align_paired_end
+  files:
+    - path: output/minimap2/test.paf
+      md5: b57e4009b113dcd48755cb713f613942
+
+- name: minimap2 align pairwise
+  command: nextflow run ./tests/software/minimap2/align -entry test_minimap2_align_pairwise -c tests/config/nextflow.config
+  tags:
+    - minimap2
+    - minimap2_align
+    - minimap2_align_pairwise
+  files:
+    - path: output/minimap2/test.paf