// Import generic module functions
include { initOptions; saveFiles; getSoftwareName } from './functions'

params.options = [:]
def options    = initOptions(params.options)

process PANGOLIN {
    tag "$meta.id"
    label 'process_medium'
    publishDir "${params.outdir}",
        mode: params.publish_dir_mode,
        saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), publish_id:meta.id) }

    conda (params.enable_conda ? 'bioconda::pangolin=2.1.7' : null)
    if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
        container 'https://depot.galaxyproject.org/singularity/pangolin:2.1.7--py_0'
    } else {
        container 'quay.io/biocontainers/pangolin:2.1.7--py_0'
    }

    input:
    tuple val(meta), path(assembly)

    output:
    tuple val(meta), path('*.lineage_report.csv') , emit: lineage
    path  '*.version.txt'                         , emit: version

    script:
    def software = getSoftwareName(task.process)
    def prefix   = options.suffix ? "${meta.id}.${options.suffix}" : "${meta.id}"
    """
    pangolin \\
    $assembly \\
    --outfile ${prefix}.lineage_report.csv \\
    $options.args

    pangolin --version | sed "s/pangolin //g" > ${software}.version.txt
    """
}