mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-09-21 07:42:05 +00:00
ac1e6df076
* Make samtools/merge cram compliant * samtools/stats cram compliance * update yml file * samtools/view to deal with crams * Update tests to make sure cram works * also fix tmp dir and min mem in one go * basequalityrecal test for cram + min mem + tmpdir * update haplotypecaller for sarek * update haplotype yml * update markdup to allow multiple bams, take out params to be passed with options.args * remove TODO statement * Remove variable md5sum * add emtpy input to stats module in subworkflows * subworkflows seem to work now on my side * Apply code review Co-authored-by: Maxime U. Garcia <maxime.garcia@scilifelab.se> * replace bam with input to be more inclusive * rename everywhere * rename input * remove variable checksum Co-authored-by: Maxime U. Garcia <maxime.garcia@scilifelab.se>
59 lines
1.9 KiB
Text
59 lines
1.9 KiB
Text
// Import generic module functions
|
|
include { initOptions; saveFiles; getSoftwareName; getProcessName } from './functions'
|
|
|
|
params.options = [:]
|
|
options = initOptions(params.options)
|
|
|
|
process GATK4_BASERECALIBRATOR {
|
|
tag "$meta.id"
|
|
label 'process_low'
|
|
publishDir "${params.outdir}",
|
|
mode: params.publish_dir_mode,
|
|
saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), meta:meta, publish_by_meta:['id']) }
|
|
|
|
conda (params.enable_conda ? "bioconda::gatk4=4.2.0.0" : null)
|
|
if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
|
|
container "https://depot.galaxyproject.org/singularity/gatk4:4.2.0.0--0"
|
|
} else {
|
|
container "quay.io/biocontainers/gatk4:4.2.0.0--0"
|
|
}
|
|
|
|
input:
|
|
tuple val(meta), path(input), path(input_index)
|
|
path fasta
|
|
path fastaidx
|
|
path dict
|
|
path intervalsBed
|
|
path knownSites
|
|
path knownSites_tbi
|
|
|
|
output:
|
|
tuple val(meta), path("*.table"), emit: table
|
|
path "versions.yml" , emit: versions
|
|
|
|
script:
|
|
def prefix = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
|
|
def intervalsCommand = intervalsBed ? "-L ${intervalsBed}" : ""
|
|
def sitesCommand = knownSites.collect{"--known-sites ${it}"}.join(' ')
|
|
|
|
if (!task.memory) {
|
|
log.info '[GATK BaseRecalibrator] Available memory not known - defaulting to 3GB. Specify process memory requirements to change this.'
|
|
} else {
|
|
avail_mem = task.memory.giga
|
|
}
|
|
"""
|
|
gatk BaseRecalibrator \
|
|
-R $fasta \
|
|
-I $input \
|
|
$sitesCommand \
|
|
$intervalsCommand \
|
|
--tmp-dir . \
|
|
$options.args \
|
|
-O ${prefix}.table
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
${getProcessName(task.process)}:
|
|
${getSoftwareName(task.process)}: \$(echo \$(gatk --version 2>&1) | sed 's/^.*(GATK) v//; s/ .*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|