mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-09-21 07:42:05 +00:00
90aef30f43
* Set process label to `process_single` for modules with no `task.cpus` usage * Fix tests of 'borked' modules * prettier * More modules are single-threaded and can use process_single * Adding process_single to hmmer/esl* modules * Fix failing tests * Prettier Co-authored-by: Matthieu Muffato <mm49@sanger.ac.uk> Co-authored-by: Daniel Lundin <erik.rikard.daniel@gmail.com>
54 lines
1.5 KiB
Text
54 lines
1.5 KiB
Text
process GATK_INDELREALIGNER {
|
|
tag "$meta.id"
|
|
label 'process_single'
|
|
|
|
conda (params.enable_conda ? "bioconda::gatk=3.5" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/gatk:3.5--hdfd78af_11':
|
|
'quay.io/biocontainers/gatk:3.5--hdfd78af_11' }"
|
|
|
|
input:
|
|
tuple val(meta), path(bam), path(bai), path(intervals)
|
|
path(fasta)
|
|
path(fai)
|
|
path(dict)
|
|
path(known_vcf)
|
|
|
|
output:
|
|
tuple val(meta), path("*.bam"), path("*.bai"), emit: bam
|
|
path "versions.yml" , emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
def known = known_vcf ? "-known ${known_vcf}" : ""
|
|
|
|
if ("$bam" == "${prefix}.bam") error "Input and output names are the same, set prefix in module configuration to disambiguate!"
|
|
|
|
def avail_mem = 3
|
|
if (!task.memory) {
|
|
log.info '[GATK IndelRealigner] Available memory not known - defaulting to 3GB. Specify process memory requirements to change this.'
|
|
} else {
|
|
avail_mem = task.memory.giga
|
|
}
|
|
|
|
"""
|
|
gatk3 \\
|
|
-Xmx${avail_mem}g \\
|
|
-T IndelRealigner \\
|
|
-R ${fasta} \\
|
|
-I ${bam} \\
|
|
--targetIntervals ${intervals} \\
|
|
${known} \\
|
|
-o ${prefix}.bam \\
|
|
$args
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
gatk: \$(echo \$(gatk3 --version))
|
|
END_VERSIONS
|
|
"""
|
|
}
|