mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-11 04:33:10 +00:00
572abb00b3
* Remove def from module options definition in main
* Fix bismark_deduplicate tests
* Fix bwameth_align tests
* Fixing gatk4 conda tests ("=" instead of ':' in build id)
* Same as previous commit (Fix gatk4 test)
* Fix qualimap bamqc test (no md5 check for pngs)
* Fix seqkit split2 tests. Changed to new test data
* Fix samtools tests. Some were missing initOptions include
* Removing TOOL SUBTOOL template module since now it is included on tools repo
46 lines
1.5 KiB
Text
46 lines
1.5 KiB
Text
// Import generic module functions
|
|
include { initOptions; saveFiles; getSoftwareName } from './functions'
|
|
|
|
params.options = [:]
|
|
options = initOptions(params.options)
|
|
|
|
process BWAMETH_ALIGN {
|
|
tag "$meta.id"
|
|
label 'process_high'
|
|
publishDir "${params.outdir}",
|
|
mode: params.publish_dir_mode,
|
|
saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), publish_id:meta.id) }
|
|
|
|
conda (params.enable_conda ? "bioconda::bwameth=0.2.2" : null)
|
|
if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
|
|
container "https://depot.galaxyproject.org/singularity/bwameth:0.20--py35_0"
|
|
} else {
|
|
container "quay.io/biocontainers/bwameth:0.20--py35_0"
|
|
}
|
|
|
|
input:
|
|
tuple val(meta), path(reads)
|
|
path index
|
|
|
|
output:
|
|
tuple val(meta), path("*.bam"), emit: bam
|
|
path "*.version.txt" , emit: version
|
|
|
|
script:
|
|
def software = getSoftwareName(task.process)
|
|
def prefix = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
|
|
def read_group = meta.read_group ? "-R ${meta.read_group}" : ""
|
|
"""
|
|
INDEX=`find -L ${index} -name "*.bwameth.c2t" | sed 's/.bwameth.c2t//'`
|
|
|
|
bwameth.py \\
|
|
$options.args \\
|
|
$read_group \\
|
|
-t $task.cpus \\
|
|
--reference \$INDEX \\
|
|
$reads \\
|
|
| samtools view $options.args2 -@ $task.cpus -bhS -o ${prefix}.bam -
|
|
|
|
echo \$(bwameth.py --version 2>&1) | cut -f2 -d" " > ${software}.version.txt
|
|
"""
|
|
}
|