mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-11 12:43:09 +00:00
3f4eccbf0f
* testing works but need to fix paths and add exclude list * edited meta file and removed TODOs * left over TODOs * test passed, final push * resolving initial comments * Update software/delly/call/main.nf Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com> Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com>
44 lines
1.4 KiB
Text
44 lines
1.4 KiB
Text
// Import generic module functions
|
|
include { initOptions; saveFiles; getSoftwareName } from './functions'
|
|
|
|
params.options = [:]
|
|
options = initOptions(params.options)
|
|
|
|
process DELLY_CALL {
|
|
tag "$meta.id"
|
|
label 'process_medium'
|
|
publishDir "${params.outdir}",
|
|
mode: params.publish_dir_mode,
|
|
saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), meta:meta, publish_by_meta:['id']) }
|
|
|
|
conda (params.enable_conda ? "bioconda::delly=0.8.7" : null)
|
|
if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
|
|
container "https://depot.galaxyproject.org/singularity/delly:0.8.7--he03298f_1"
|
|
} else {
|
|
container "quay.io/biocontainers/delly:0.8.7--he03298f_1"
|
|
}
|
|
|
|
input:
|
|
tuple val(meta), path(bam), path(bai)
|
|
path fasta
|
|
path fai
|
|
|
|
output:
|
|
tuple val(meta), path("*.bcf"), emit: bcf
|
|
tuple val(meta), path("*.csi"), emit: csi
|
|
path "*.version.txt" , emit: version
|
|
|
|
script:
|
|
def software = getSoftwareName(task.process)
|
|
def prefix = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
|
|
"""
|
|
delly \\
|
|
call \\
|
|
$options.args \\
|
|
-o ${prefix}.bcf \\
|
|
-g $fasta \\
|
|
$bam \\
|
|
|
|
echo \$(delly --version 2>&1) | sed 's/^.*Delly //; s/Using.*\$//' > ${software}.version.txt
|
|
"""
|
|
}
|