mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-10 20:23:10 +00:00
409af2f27c
* feat: code polishing * Apply suggestions from code review Co-authored-by: FriederikeHanssen <Friederike.hanssen@qbic.uni-tuebingen.de> * code polishing * more code polishing * code polishing * tests for applybqsrspark * fix typo * no need to check md5sum for versions.yml * fix: use correct syntax * code polishing again * add tests for markduplicatesspark * simplify mergevcfs tests * add tests for baserecalibratorspark * fix: path to entry * code polishing * fix linting * simplify module * update meta.yml * fix pair mode * fix: MITO mode * more tests * fix command * bad copy paste * fix typos * fix tests * fix test * update meta.yml * correct versions.yml in all test.yml * code polishing * code polishing * more code polishing * fix args * add tmpdir for all Co-authored-by: FriederikeHanssen <Friederike.hanssen@qbic.uni-tuebingen.de>
60 lines
2 KiB
Text
60 lines
2 KiB
Text
process GATK4_MUTECT2 {
|
|
tag "$meta.id"
|
|
label 'process_medium'
|
|
|
|
conda (params.enable_conda ? "bioconda::gatk4=4.2.5.0" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/gatk4:4.2.5.0--hdfd78af_0' :
|
|
'quay.io/biocontainers/gatk4:4.2.5.0--hdfd78af_0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(input), path(input_index), path(intervals)
|
|
path fasta
|
|
path fai
|
|
path dict
|
|
path germline_resource
|
|
path germline_resource_tbi
|
|
path panel_of_normals
|
|
path panel_of_normals_tbi
|
|
|
|
output:
|
|
tuple val(meta), path("*.vcf.gz") , emit: vcf
|
|
tuple val(meta), path("*.tbi") , emit: tbi
|
|
tuple val(meta), path("*.stats") , emit: stats
|
|
tuple val(meta), path("*.f1r2.tar.gz"), optional:true, emit: f1r2
|
|
path "versions.yml" , emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
def inputs = input.collect{ "--input $it"}.join(" ")
|
|
def interval_command = intervals ? "--intervals $intervals" : ""
|
|
def pon_command = panel_of_normals ? "--panel-of-normals $panel_of_normals" : ""
|
|
def gr_command = germline_resource ? "--germline-resource $germline_resource" : ""
|
|
|
|
def avail_mem = 3
|
|
if (!task.memory) {
|
|
log.info '[GATK Mutect2] Available memory not known - defaulting to 3GB. Specify process memory requirements to change this.'
|
|
} else {
|
|
avail_mem = task.memory.giga
|
|
}
|
|
"""
|
|
gatk --java-options "-Xmx${avail_mem}g" Mutect2 \\
|
|
$inputs \\
|
|
--output ${prefix}.vcf.gz \\
|
|
--reference $fasta \\
|
|
$pon_command \\
|
|
$gr_command \\
|
|
$interval_command \\
|
|
--tmp-dir . \\
|
|
$args
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
gatk4: \$(echo \$(gatk --version 2>&1) | sed 's/^.*(GATK) v//; s/ .*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|