mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-09-21 15:52:05 +00:00
ac1e6df076
* Make samtools/merge cram compliant * samtools/stats cram compliance * update yml file * samtools/view to deal with crams * Update tests to make sure cram works * also fix tmp dir and min mem in one go * basequalityrecal test for cram + min mem + tmpdir * update haplotypecaller for sarek * update haplotype yml * update markdup to allow multiple bams, take out params to be passed with options.args * remove TODO statement * Remove variable md5sum * add emtpy input to stats module in subworkflows * subworkflows seem to work now on my side * Apply code review Co-authored-by: Maxime U. Garcia <maxime.garcia@scilifelab.se> * replace bam with input to be more inclusive * rename everywhere * rename input * remove variable checksum Co-authored-by: Maxime U. Garcia <maxime.garcia@scilifelab.se>
68 lines
2.7 KiB
Text
68 lines
2.7 KiB
Text
// Import generic module functions
|
|
include { initOptions; saveFiles; getSoftwareName; getProcessName } from './functions'
|
|
|
|
params.options = [:]
|
|
options = initOptions(params.options)
|
|
|
|
process MANTA_TUMORONLY {
|
|
tag "$meta.id"
|
|
label 'process_high'
|
|
publishDir "${params.outdir}",
|
|
mode: params.publish_dir_mode,
|
|
saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), meta:meta, publish_by_meta:['id']) }
|
|
|
|
conda (params.enable_conda ? "bioconda::manta=1.6.0" : null)
|
|
if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
|
|
container "https://depot.galaxyproject.org/singularity/manta:1.6.0--h9ee0642_1"
|
|
} else {
|
|
container "quay.io/biocontainers/manta:1.6.0--h9ee0642_1"
|
|
}
|
|
|
|
input:
|
|
tuple val(meta), path(input), path(input_index)
|
|
path fasta
|
|
path fai
|
|
path target_bed
|
|
path target_bed_tbi
|
|
|
|
output:
|
|
tuple val(meta), path("*candidate_small_indels.vcf.gz") , emit: candidate_small_indels_vcf
|
|
tuple val(meta), path("*candidate_small_indels.vcf.gz.tbi"), emit: candidate_small_indels_vcf_tbi
|
|
tuple val(meta), path("*candidate_sv.vcf.gz") , emit: candidate_sv_vcf
|
|
tuple val(meta), path("*candidate_sv.vcf.gz.tbi") , emit: candidate_sv_vcf_tbi
|
|
tuple val(meta), path("*tumor_sv.vcf.gz") , emit: tumor_sv_vcf
|
|
tuple val(meta), path("*tumor_sv.vcf.gz.tbi") , emit: tumor_sv_vcf_tbi
|
|
path "versions.yml" , emit: versions
|
|
|
|
script:
|
|
def prefix = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
|
|
def options_manta = target_bed ? "--exome --callRegions $target_bed" : ""
|
|
"""
|
|
configManta.py \
|
|
--tumorBam $input \
|
|
--reference $fasta \
|
|
$options_manta \
|
|
--runDir manta
|
|
|
|
python manta/runWorkflow.py -m local -j $task.cpus
|
|
|
|
mv manta/results/variants/candidateSmallIndels.vcf.gz \
|
|
${prefix}.candidate_small_indels.vcf.gz
|
|
mv manta/results/variants/candidateSmallIndels.vcf.gz.tbi \
|
|
${prefix}.candidate_small_indels.vcf.gz.tbi
|
|
mv manta/results/variants/candidateSV.vcf.gz \
|
|
${prefix}.candidate_sv.vcf.gz
|
|
mv manta/results/variants/candidateSV.vcf.gz.tbi \
|
|
${prefix}.candidate_sv.vcf.gz.tbi
|
|
mv manta/results/variants/tumorSV.vcf.gz \
|
|
${prefix}.tumor_sv.vcf.gz
|
|
mv manta/results/variants/tumorSV.vcf.gz.tbi \
|
|
${prefix}.tumor_sv.vcf.gz.tbi
|
|
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
${getProcessName(task.process)}:
|
|
${getSoftwareName(task.process)}: \$( configManta.py --version )
|
|
END_VERSIONS
|
|
"""
|
|
}
|