mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-11 12:43:09 +00:00
572abb00b3
* Remove def from module options definition in main
* Fix bismark_deduplicate tests
* Fix bwameth_align tests
* Fixing gatk4 conda tests ("=" instead of ':' in build id)
* Same as previous commit (Fix gatk4 test)
* Fix qualimap bamqc test (no md5 check for pngs)
* Fix seqkit split2 tests. Changed to new test data
* Fix samtools tests. Some were missing initOptions include
* Removing TOOL SUBTOOL template module since now it is included on tools repo
49 lines
1.7 KiB
Text
49 lines
1.7 KiB
Text
// Import generic module functions
|
|
include { initOptions; saveFiles; getSoftwareName } from './functions'
|
|
|
|
params.options = [:]
|
|
options = initOptions(params.options)
|
|
|
|
process PICARD_MARKDUPLICATES {
|
|
tag "$meta.id"
|
|
label 'process_medium'
|
|
publishDir "${params.outdir}",
|
|
mode: params.publish_dir_mode,
|
|
saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), publish_id:meta.id) }
|
|
|
|
conda (params.enable_conda ? "bioconda::picard=2.23.9" : null)
|
|
if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
|
|
container "https://depot.galaxyproject.org/singularity/picard:2.23.9--0"
|
|
} else {
|
|
container "quay.io/biocontainers/picard:2.23.9--0"
|
|
}
|
|
|
|
input:
|
|
tuple val(meta), path(bam)
|
|
|
|
output:
|
|
tuple val(meta), path("*.bam") , emit: bam
|
|
tuple val(meta), path("*.metrics.txt"), emit: metrics
|
|
path "*.version.txt" , emit: version
|
|
|
|
script:
|
|
def software = getSoftwareName(task.process)
|
|
def prefix = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
|
|
def avail_mem = 3
|
|
if (!task.memory) {
|
|
log.info '[Picard MarkDuplicates] Available memory not known - defaulting to 3GB. Specify process memory requirements to change this.'
|
|
} else {
|
|
avail_mem = task.memory.giga
|
|
}
|
|
"""
|
|
picard \\
|
|
-Xmx${avail_mem}g \\
|
|
MarkDuplicates \\
|
|
$options.args \\
|
|
INPUT=$bam \\
|
|
OUTPUT=${prefix}.bam \\
|
|
METRICS_FILE=${prefix}.MarkDuplicates.metrics.txt
|
|
|
|
echo \$(picard MarkDuplicates --version 2>&1) | grep -o 'Version:.*' | cut -f2- -d: > ${software}.version.txt
|
|
"""
|
|
}
|