mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-15 14:13:09 +00:00
83b05a8dc0
* add qname feature to samtools_view * update tests * Update modules/samtools/view/meta.yml Co-authored-by: James A. Fellows Yates <jfy133@gmail.com> * Update modules/samtools/view/meta.yml Co-authored-by: James A. Fellows Yates <jfy133@gmail.com> * added filter tests Co-authored-by: James A. Fellows Yates <jfy133@gmail.com>
64 lines
2.2 KiB
Text
64 lines
2.2 KiB
Text
process SAMTOOLS_VIEW {
|
|
tag "$meta.id"
|
|
label 'process_low'
|
|
|
|
conda (params.enable_conda ? "bioconda::samtools=1.15.1" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/samtools:1.15.1--h1170115_0' :
|
|
'quay.io/biocontainers/samtools:1.15.1--h1170115_0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(input), path(index)
|
|
path fasta
|
|
path qname
|
|
|
|
output:
|
|
tuple val(meta), path("*.bam"), emit: bam, optional: true
|
|
tuple val(meta), path("*.cram"), emit: cram, optional: true
|
|
tuple val(meta), path("*.sam"), emit: sam, optional: true
|
|
tuple val(meta), path("*.bai"), emit: bai, optional: true
|
|
tuple val(meta), path("*.csi"), emit: csi, optional: true
|
|
tuple val(meta), path("*.crai"), emit: crai, optional: true
|
|
path "versions.yml", emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
def reference = fasta ? "--reference ${fasta}" : ""
|
|
def readnames = qname ? "--qname-file ${qname}": ""
|
|
def file_type = args.contains("--output-fmt sam") ? "sam" :
|
|
args.contains("--output-fmt bam") ? "bam" :
|
|
args.contains("--output-fmt cram") ? "cram" :
|
|
input.getExtension()
|
|
if ("$input" == "${prefix}.${file_type}") error "Input and output names are the same, use \"task.ext.prefix\" to disambiguate!"
|
|
"""
|
|
samtools \\
|
|
view \\
|
|
--threads ${task.cpus-1} \\
|
|
${reference} \\
|
|
${readnames} \\
|
|
$args \\
|
|
-o ${prefix}.${file_type} \\
|
|
$input
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
samtools: \$(echo \$(samtools --version 2>&1) | sed 's/^.*samtools //; s/Using.*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
|
|
stub:
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
"""
|
|
touch ${prefix}.bam
|
|
touch ${prefix}.cram
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
samtools: \$(echo \$(samtools --version 2>&1) | sed 's/^.*samtools //; s/Using.*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|