mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-11 04:33:10 +00:00
50eafb19c6
* Update version for log4j vulnerability * update checksums * update checksums * update checksums * Remove todo string * remove werid output paths * remove werid output paths * remove werid output paths * Update various checksums * Update various checksums * Remove unstable md5sums * Update md5sums * Fix pileupsummary * Fix genotypegvcfs * Update test files mutect2 * hm genotypevcf updated again * Update some mutect checksums and whatnot * Fix last mutect checksum * Apply suggestion to use mtochondria data instead
63 lines
2.4 KiB
Text
63 lines
2.4 KiB
Text
process GATK4_GENOMICSDBIMPORT {
|
|
tag "$meta.id"
|
|
label 'process_low'
|
|
|
|
conda (params.enable_conda ? "bioconda::gatk4=4.2.4.0" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/gatk4:4.2.4.0--hdfd78af_0' :
|
|
'quay.io/biocontainers/gatk4:4.2.4.0--hdfd78af_0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(vcf), path(tbi), path(intervalfile), val(intervalval), path(wspace)
|
|
val run_intlist
|
|
val run_updatewspace
|
|
val input_map
|
|
|
|
output:
|
|
tuple val(meta), path("${prefix}") , optional:true, emit: genomicsdb
|
|
tuple val(meta), path("$updated_db") , optional:true, emit: updatedb
|
|
tuple val(meta), path("*.interval_list"), optional:true, emit: intervallist
|
|
path "versions.yml" , emit: versions
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
prefix = task.ext.prefix ?: "${meta.id}"
|
|
|
|
// settings for running default create gendb mode
|
|
inputs_command = input_map ? "--sample-name-map ${vcf[0]}" : "${'-V ' + vcf.join(' -V ')}"
|
|
dir_command = "--genomicsdb-workspace-path ${prefix}"
|
|
intervals_command = intervalfile ? " -L ${intervalfile} " : " -L ${intervalval} "
|
|
|
|
// settings changed for running get intervals list mode if run_intlist is true
|
|
if (run_intlist) {
|
|
inputs_command = ''
|
|
dir_command = "--genomicsdb-update-workspace-path ${wspace}"
|
|
intervals_command = "--output-interval-list-to-file ${prefix}.interval_list"
|
|
}
|
|
|
|
// settings changed for running update gendb mode. inputs_command same as default, update_db forces module to emit the updated gendb
|
|
if (run_updatewspace) {
|
|
dir_command = "--genomicsdb-update-workspace-path ${wspace}"
|
|
intervals_command = ''
|
|
updated_db = wspace.toString()
|
|
}
|
|
|
|
def avail_mem = 3
|
|
if (!task.memory) {
|
|
log.info '[GATK GenomicsDBImport] Available memory not known - defaulting to 3GB. Specify process memory requirements to change this.'
|
|
} else {
|
|
avail_mem = task.memory.giga
|
|
}
|
|
"""
|
|
gatk --java-options "-Xmx${avail_mem}g" GenomicsDBImport \\
|
|
$inputs_command \\
|
|
$dir_command \\
|
|
$intervals_command \\
|
|
$args
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
gatk4: \$(echo \$(gatk --version 2>&1) | sed 's/^.*(GATK) v//; s/ .*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|