mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-12-26 12:28:17 +00:00
e937c7950a
* Update README * Rename pytest_software.yml to pytest_modules.yml * Rename main software directory to modules * Remove deprecated modules * Rename tests software to modules * Replace paths for tests in pytest_modules.yml * Replace software with modules in Github Actions * Replace software with modules in main.nf tests * Rename software to modules in test.yml
93 lines
3.5 KiB
Text
93 lines
3.5 KiB
Text
// Import generic module functions
|
|
include { initOptions; saveFiles; getSoftwareName } from './functions'
|
|
|
|
params.options = [:]
|
|
options = initOptions(params.options)
|
|
|
|
def VERSION = '2.2.0'
|
|
|
|
process HISAT2_ALIGN {
|
|
tag "$meta.id"
|
|
label 'process_high'
|
|
publishDir "${params.outdir}",
|
|
mode: params.publish_dir_mode,
|
|
saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), meta:meta, publish_by_meta:['id']) }
|
|
|
|
conda (params.enable_conda ? "bioconda::hisat2=2.2.0 bioconda::samtools=1.10" : null)
|
|
if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
|
|
container "https://depot.galaxyproject.org/singularity/mulled-v2-a97e90b3b802d1da3d6958e0867610c718cb5eb1:2880dd9d8ad0a7b221d4eacda9a818e92983128d-0"
|
|
} else {
|
|
container "quay.io/biocontainers/mulled-v2-a97e90b3b802d1da3d6958e0867610c718cb5eb1:2880dd9d8ad0a7b221d4eacda9a818e92983128d-0"
|
|
}
|
|
|
|
input:
|
|
tuple val(meta), path(reads)
|
|
path index
|
|
path splicesites
|
|
|
|
output:
|
|
tuple val(meta), path("*.bam"), emit: bam
|
|
tuple val(meta), path("*.log"), emit: summary
|
|
path "*.version.txt" , emit: version
|
|
|
|
tuple val(meta), path("*fastq.gz"), optional:true, emit: fastq
|
|
|
|
script:
|
|
def software = getSoftwareName(task.process)
|
|
def prefix = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
|
|
|
|
def strandedness = ''
|
|
if (meta.strandedness == 'forward') {
|
|
strandedness = meta.single_end ? '--rna-strandness F' : '--rna-strandness FR'
|
|
} else if (meta.strandedness == 'reverse') {
|
|
strandedness = meta.single_end ? '--rna-strandness R' : '--rna-strandness RF'
|
|
}
|
|
def seq_center = params.seq_center ? "--rg-id ${prefix} --rg SM:$prefix --rg CN:${params.seq_center.replaceAll('\\s','_')}" : "--rg-id ${prefix} --rg SM:$prefix"
|
|
if (meta.single_end) {
|
|
def unaligned = params.save_unaligned ? "--un-gz ${prefix}.unmapped.fastq.gz" : ''
|
|
"""
|
|
INDEX=`find -L ./ -name "*.1.ht2" | sed 's/.1.ht2//'`
|
|
hisat2 \\
|
|
-x \$INDEX \\
|
|
-U $reads \\
|
|
$strandedness \\
|
|
--known-splicesite-infile $splicesites \\
|
|
--summary-file ${prefix}.hisat2.summary.log \\
|
|
--threads $task.cpus \\
|
|
$seq_center \\
|
|
$unaligned \\
|
|
$options.args \\
|
|
| samtools view -bS -F 4 -F 256 - > ${prefix}.bam
|
|
|
|
echo $VERSION > ${software}.version.txt
|
|
"""
|
|
} else {
|
|
def unaligned = params.save_unaligned ? "--un-conc-gz ${prefix}.unmapped.fastq.gz" : ''
|
|
"""
|
|
INDEX=`find -L ./ -name "*.1.ht2" | sed 's/.1.ht2//'`
|
|
hisat2 \\
|
|
-x \$INDEX \\
|
|
-1 ${reads[0]} \\
|
|
-2 ${reads[1]} \\
|
|
$strandedness \\
|
|
--known-splicesite-infile $splicesites \\
|
|
--summary-file ${prefix}.hisat2.summary.log \\
|
|
--threads $task.cpus \\
|
|
$seq_center \\
|
|
$unaligned \\
|
|
--no-mixed \\
|
|
--no-discordant \\
|
|
$options.args \\
|
|
| samtools view -bS -F 4 -F 8 -F 256 - > ${prefix}.bam
|
|
|
|
if [ -f ${prefix}.unmapped.fastq.1.gz ]; then
|
|
mv ${prefix}.unmapped.fastq.1.gz ${prefix}.unmapped_1.fastq.gz
|
|
fi
|
|
if [ -f ${prefix}.unmapped.fastq.2.gz ]; then
|
|
mv ${prefix}.unmapped.fastq.2.gz ${prefix}.unmapped_2.fastq.gz
|
|
fi
|
|
|
|
echo $VERSION > ${software}.version.txt
|
|
"""
|
|
}
|
|
}
|