mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-09-21 15:52:05 +00:00
09acfad211
* added the module * updated test.yml * Update modules/gatk4/collectreadcounts/main.nf Co-authored-by: FriederikeHanssen <Friederike.hanssen@qbic.uni-tuebingen.de> * small fix * tests update * linting * tests update (again) Co-authored-by: FriederikeHanssen <Friederike.hanssen@qbic.uni-tuebingen.de>
53 lines
1.7 KiB
Text
53 lines
1.7 KiB
Text
process GATK4_COLLECTREADCOUNTS {
|
|
tag "$meta.id"
|
|
label 'process_medium'
|
|
|
|
conda (params.enable_conda ? "bioconda::gatk4=4.2.6.1" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/gatk4:4.2.6.1--hdfd78af_0':
|
|
'quay.io/biocontainers/gatk4:4.2.6.1--hdfd78af_0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(input), path(input_index), path(intervals)
|
|
path(fasta)
|
|
path(fai)
|
|
path(dict)
|
|
|
|
output:
|
|
tuple val(meta), path("*.hdf5"), optional: true, emit: hdf5
|
|
tuple val(meta), path("*.tsv") , optional: true, emit: tsv
|
|
path "versions.yml" , emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
|
|
def reference = fasta ? "--reference $fasta" : ""
|
|
def extension = args.contains("--format HDF5") ? "hdf5" :
|
|
args.contains("--format TSV") ? "tsv" :
|
|
"hdf5"
|
|
|
|
def avail_mem = 3
|
|
if (!task.memory) {
|
|
log.info '[GATK COLLECTREADCOUNTS] Available memory not known - defaulting to 3GB. Specify process memory requirements to change this.'
|
|
} else {
|
|
avail_mem = task.memory.giga
|
|
}
|
|
"""
|
|
gatk --java-options "-Xmx${avail_mem}g" CollectReadCounts \\
|
|
--input $input \\
|
|
--intervals $intervals \\
|
|
--output ${prefix}.$extension \\
|
|
$reference \\
|
|
--tmp-dir . \\
|
|
$args
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
gatk4: \$(echo \$(gatk --version 2>&1) | sed 's/^.*(GATK) v//; s/ .*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|