mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-14 13:43:09 +00:00
bb90e4fb78
* Remove customisation from bcftools modules * Add save_mpileup option to bcftools/mpileup * Remove params.save_mpileup from ivar/consensus * Update meta.ymls
50 lines
1.6 KiB
Text
50 lines
1.6 KiB
Text
process BCFTOOLS_MPILEUP {
|
|
tag "$meta.id"
|
|
label 'process_medium'
|
|
|
|
conda (params.enable_conda ? 'bioconda::bcftools=1.14' : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/bcftools:1.14--h88f3f91_0' :
|
|
'quay.io/biocontainers/bcftools:1.14--h88f3f91_0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(bam)
|
|
path fasta
|
|
val save_mpileup
|
|
|
|
output:
|
|
tuple val(meta), path("*.gz") , emit: vcf
|
|
tuple val(meta), path("*.tbi") , emit: tbi
|
|
tuple val(meta), path("*stats.txt"), emit: stats
|
|
tuple val(meta), path("*.mpileup") , emit: mpileup, optional: true
|
|
path "versions.yml" , emit: versions
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def args2 = task.ext.args2 ?: ''
|
|
def args3 = task.ext.args3 ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
def mpileup = save_mpileup ? "| tee ${prefix}.mpileup" : ""
|
|
"""
|
|
echo "${meta.id}" > sample_name.list
|
|
|
|
bcftools \\
|
|
mpileup \\
|
|
--fasta-ref $fasta \\
|
|
$args \\
|
|
$bam \\
|
|
$mpileup \\
|
|
| bcftools call --output-type v $args2 \\
|
|
| bcftools reheader --samples sample_name.list \\
|
|
| bcftools view --output-file ${prefix}.vcf.gz --output-type z $args3
|
|
|
|
tabix -p vcf -f ${prefix}.vcf.gz
|
|
|
|
bcftools stats ${prefix}.vcf.gz > ${prefix}.bcftools_stats.txt
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
bcftools: \$(bcftools --version 2>&1 | head -n1 | sed 's/^.*bcftools //; s/ .*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|