mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-15 14:13:09 +00:00
30b0485912
* Added support for meta in bwamem2/index * Added missing description of the input meta map (fasta file) * Made bwamem2/mem aware of the meta map the index carries * The output meta map needs to be same as the input bam file Don't merge it with the index's Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com> Co-authored-by: Harshil Patel <drpatelh@users.noreply.github.com>
55 lines
1.8 KiB
Text
55 lines
1.8 KiB
Text
process BWAMEM2_MEM {
|
|
tag "$meta.id"
|
|
label 'process_high'
|
|
|
|
conda (params.enable_conda ? "bioconda::bwa-mem2=2.2.1 bioconda::samtools=1.15.1" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/mulled-v2-e5d375990341c5aef3c9aff74f96f66f65375ef6:38aed4501da19db366dc7c8d52d31d94e760cfaf-0' :
|
|
'quay.io/biocontainers/mulled-v2-e5d375990341c5aef3c9aff74f96f66f65375ef6:38aed4501da19db366dc7c8d52d31d94e760cfaf-0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(reads)
|
|
tuple val(meta2), path(index)
|
|
val sort_bam
|
|
|
|
output:
|
|
tuple val(meta), path("*.bam"), emit: bam
|
|
path "versions.yml" , emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def args2 = task.ext.args2 ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
def samtools_command = sort_bam ? 'sort' : 'view'
|
|
"""
|
|
INDEX=`find -L ./ -name "*.amb" | sed 's/.amb//'`
|
|
|
|
bwa-mem2 \\
|
|
mem \\
|
|
$args \\
|
|
-t $task.cpus \\
|
|
\$INDEX \\
|
|
$reads \\
|
|
| samtools $samtools_command $args2 -@ $task.cpus -o ${prefix}.bam -
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
bwamem2: \$(echo \$(bwa-mem2 version 2>&1) | sed 's/.* //')
|
|
samtools: \$(echo \$(samtools --version 2>&1) | sed 's/^.*samtools //; s/Using.*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
|
|
stub:
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
"""
|
|
touch ${prefix}.bam
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
bwamem2: \$(echo \$(bwa-mem2 version 2>&1) | sed 's/.* //')
|
|
samtools: \$(echo \$(samtools --version 2>&1) | sed 's/^.*samtools //; s/Using.*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|