mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-09-21 07:42:05 +00:00
967fb22ded
* Update versions * update checksums + remove variables as input for applyvqsr * sneak in removal of values and provide them via modules.config * update another checksum * more checksums * move vairable to config * remove controlfreec, wrong branch * add line break
46 lines
1.6 KiB
Text
46 lines
1.6 KiB
Text
process GATK4_CALCULATECONTAMINATION {
|
|
tag "$meta.id"
|
|
label 'process_low'
|
|
|
|
conda (params.enable_conda ? "bioconda::gatk4=4.2.5.0" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/gatk4:4.2.5.0--hdfd78af_0' :
|
|
'quay.io/biocontainers/gatk4:4.2.5.0--hdfd78af_0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(pileup), path(matched)
|
|
val segmentout
|
|
|
|
output:
|
|
tuple val(meta), path('*.contamination.table'), emit: contamination
|
|
tuple val(meta), path('*.segmentation.table') , emit: segmentation, optional:true
|
|
path "versions.yml" , emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
def matched_command = matched ? " -matched ${matched} " : ''
|
|
def segment_command = segmentout ? " -segments ${prefix}.segmentation.table" : ''
|
|
def avail_mem = 3
|
|
if (!task.memory) {
|
|
log.info '[GATK CalculateContamination] Available memory not known - defaulting to 3GB. Specify process memory requirements to change this.'
|
|
} else {
|
|
avail_mem = task.memory.giga
|
|
}
|
|
"""
|
|
gatk --java-options "-Xmx${avail_mem}g" CalculateContamination \\
|
|
-I $pileup \\
|
|
$matched_command \\
|
|
-O ${prefix}.contamination.table \\
|
|
$segment_command \\
|
|
$args
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
gatk4: \$(echo \$(gatk --version 2>&1) | sed 's/^.*(GATK) v//; s/ .*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|