mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-09-21 15:52:05 +00:00
8d4373b4e8
* added bcftools convert * Update modules/bcftools/convert/main.nf Co-authored-by: Matthias De Smet <11850640+matthdsm@users.noreply.github.com> * updated test.yml * Update modules/bcftools/convert/main.nf Co-authored-by: Matthias De Smet <11850640+matthdsm@users.noreply.github.com> * added automatic output type detection * linting * removed a trailing whitespace Co-authored-by: Matthias De Smet <11850640+matthdsm@users.noreply.github.com>
51 lines
1.8 KiB
Text
51 lines
1.8 KiB
Text
process BCFTOOLS_CONVERT {
|
|
tag "$meta.id"
|
|
label 'process_medium'
|
|
|
|
conda (params.enable_conda ? "bioconda::bcftools=1.15.1" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/bcftools:1.15.1--h0ea216a_0':
|
|
'quay.io/biocontainers/bcftools:1.15.1--h0ea216a_0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(input), path(input_index)
|
|
path bed
|
|
path fasta
|
|
|
|
output:
|
|
tuple val(meta), path("*.vcf.gz"), optional:true , emit: vcf_gz
|
|
tuple val(meta), path("*.vcf") , optional:true , emit: vcf
|
|
tuple val(meta), path("*.bcf.gz"), optional:true , emit: bcf_gz
|
|
tuple val(meta), path("*.bcf") , optional:true , emit: bcf
|
|
path "versions.yml" , emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
|
|
def regions = bed ? "--regions-file $bed" : ""
|
|
def reference = fasta ? "--fasta-ref $fasta" : ""
|
|
def extension = args.contains("--output-type b") || args.contains("-Ob") ? "bcf.gz" :
|
|
args.contains("--output-type u") || args.contains("-Ou") ? "bcf" :
|
|
args.contains("--output-type z") || args.contains("-Oz") ? "vcf.gz" :
|
|
args.contains("--output-type v") || args.contains("-Ov") ? "vcf" :
|
|
"vcf.gz"
|
|
|
|
"""
|
|
bcftools convert \\
|
|
$args \\
|
|
$regions \\
|
|
--output ${prefix}.${extension} \\
|
|
--threads $task.cpus \\
|
|
$reference \\
|
|
$input
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
bcftools: \$(bcftools --version 2>&1 | head -n1 | sed 's/^.*bcftools //; s/ .*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|