mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-10 20:23:10 +00:00
e937c7950a
* Update README * Rename pytest_software.yml to pytest_modules.yml * Rename main software directory to modules * Remove deprecated modules * Rename tests software to modules * Replace paths for tests in pytest_modules.yml * Replace software with modules in Github Actions * Replace software with modules in main.nf tests * Rename software to modules in test.yml
47 lines
1.7 KiB
Text
47 lines
1.7 KiB
Text
// Import generic module functions
|
|
include { initOptions; saveFiles; getSoftwareName } from './functions'
|
|
|
|
params.options = [:]
|
|
options = initOptions(params.options)
|
|
|
|
process BWA_MEM {
|
|
tag "$meta.id"
|
|
label 'process_high'
|
|
publishDir "${params.outdir}",
|
|
mode: params.publish_dir_mode,
|
|
saveAs: { filename -> saveFiles(filename:filename, options:params.options, publish_dir:getSoftwareName(task.process), meta:meta, publish_by_meta:['id']) }
|
|
|
|
conda (params.enable_conda ? "bioconda::bwa=0.7.17 bioconda::samtools=1.12" : null)
|
|
if (workflow.containerEngine == 'singularity' && !params.singularity_pull_docker_container) {
|
|
container "https://depot.galaxyproject.org/singularity/mulled-v2-fe8faa35dbf6dc65a0f7f5d4ea12e31a79f73e40:66ed1b38d280722529bb8a0167b0cf02f8a0b488-0"
|
|
} else {
|
|
container "quay.io/biocontainers/mulled-v2-fe8faa35dbf6dc65a0f7f5d4ea12e31a79f73e40:66ed1b38d280722529bb8a0167b0cf02f8a0b488-0"
|
|
}
|
|
|
|
input:
|
|
tuple val(meta), path(reads)
|
|
path index
|
|
|
|
output:
|
|
tuple val(meta), path("*.bam"), emit: bam
|
|
path "*.version.txt" , emit: version
|
|
|
|
script:
|
|
def split_cpus = Math.floor(task.cpus/2)
|
|
def software = getSoftwareName(task.process)
|
|
def prefix = options.suffix ? "${meta.id}${options.suffix}" : "${meta.id}"
|
|
def read_group = meta.read_group ? "-R ${meta.read_group}" : ""
|
|
"""
|
|
INDEX=`find -L ./ -name "*.amb" | sed 's/.amb//'`
|
|
|
|
bwa mem \\
|
|
$options.args \\
|
|
$read_group \\
|
|
-t ${split_cpus} \\
|
|
\$INDEX \\
|
|
$reads \\
|
|
| samtools view $options.args2 -@ ${split_cpus} -bhS -o ${prefix}.bam -
|
|
|
|
echo \$(bwa 2>&1) | sed 's/^.*Version: //; s/Contact:.*\$//' > ${software}.version.txt
|
|
"""
|
|
}
|