mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-11 04:33:10 +00:00
54 lines
1.8 KiB
Text
54 lines
1.8 KiB
Text
process GATK4_VARIANTRECALIBRATOR {
|
|
tag "$meta.id"
|
|
label 'process_low'
|
|
|
|
conda (params.enable_conda ? "bioconda::gatk4=4.2.6.1" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/gatk4:4.2.6.1--hdfd78af_0':
|
|
'quay.io/biocontainers/gatk4:4.2.6.1--hdfd78af_0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(vcf), path(tbi)
|
|
tuple path(vcfs), path(tbis), val(labels)
|
|
path fasta
|
|
path fai
|
|
path dict
|
|
|
|
output:
|
|
tuple val(meta), path("*.recal") , emit: recal
|
|
tuple val(meta), path("*.idx") , emit: idx
|
|
tuple val(meta), path("*.tranches"), emit: tranches
|
|
tuple val(meta), path("*plots.R") , emit: plots, optional:true
|
|
path "versions.yml" , emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
def reference_command = fasta ? "--reference $fasta " : ''
|
|
def resource_command = labels.collect{"--resource:$it"}.join(' ')
|
|
|
|
def avail_mem = 3
|
|
if (!task.memory) {
|
|
log.info '[GATK VariantRecalibrator] Available memory not known - defaulting to 3GB. Specify process memory requirements to change this.'
|
|
} else {
|
|
avail_mem = task.memory.giga
|
|
}
|
|
"""
|
|
gatk --java-options "-Xmx${avail_mem}g" VariantRecalibrator \\
|
|
--variant $vcf \\
|
|
--output ${prefix}.recal \\
|
|
--tranches-file ${prefix}.tranches \\
|
|
$reference_command \\
|
|
$resource_command \\
|
|
--tmp-dir . \\
|
|
$args
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
gatk4: \$(echo \$(gatk --version 2>&1) | sed 's/^.*(GATK) v//; s/ .*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|