mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-11-10 20:23:10 +00:00
90aef30f43
* Set process label to `process_single` for modules with no `task.cpus` usage * Fix tests of 'borked' modules * prettier * More modules are single-threaded and can use process_single * Adding process_single to hmmer/esl* modules * Fix failing tests * Prettier Co-authored-by: Matthieu Muffato <mm49@sanger.ac.uk> Co-authored-by: Daniel Lundin <erik.rikard.daniel@gmail.com>
59 lines
1.7 KiB
Text
59 lines
1.7 KiB
Text
process BEDTOOLS_GENOMECOV {
|
|
tag "$meta.id"
|
|
label 'process_single'
|
|
|
|
conda (params.enable_conda ? "bioconda::bedtools=2.30.0" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/bedtools:2.30.0--hc088bd4_0' :
|
|
'quay.io/biocontainers/bedtools:2.30.0--hc088bd4_0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(intervals), val(scale)
|
|
path sizes
|
|
val extension
|
|
|
|
output:
|
|
tuple val(meta), path("*.${extension}"), emit: genomecov
|
|
path "versions.yml" , emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def args_list = args.tokenize()
|
|
args += (scale > 0 && scale != 1) ? " -scale $scale" : ""
|
|
if (!args_list.contains('-bg') && (scale > 0 && scale != 1)) {
|
|
args += " -bg"
|
|
}
|
|
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
if (intervals.name =~ /\.bam/) {
|
|
"""
|
|
bedtools \\
|
|
genomecov \\
|
|
-ibam $intervals \\
|
|
$args \\
|
|
> ${prefix}.${extension}
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
bedtools: \$(bedtools --version | sed -e "s/bedtools v//g")
|
|
END_VERSIONS
|
|
"""
|
|
} else {
|
|
"""
|
|
bedtools \\
|
|
genomecov \\
|
|
-i $intervals \\
|
|
-g $sizes \\
|
|
$args \\
|
|
> ${prefix}.${extension}
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
bedtools: \$(bedtools --version | sed -e "s/bedtools v//g")
|
|
END_VERSIONS
|
|
"""
|
|
}
|
|
}
|