mirror of
https://github.com/MillironX/nf-core_modules.git
synced 2024-12-25 12:08:16 +00:00
49b18b1639
* add stub section * add stub for bcftools norm * add stub to more modules * fix expansionhunter tests * revert changes -picard * Update stub to write version no.s to a file * add picard * revert picard again * add stubs to more modules * fix bwamem2 * add bcftools view * add stubs * fix svdb query * review suggestions
57 lines
1.9 KiB
Text
57 lines
1.9 KiB
Text
process BWAMEM2_MEM {
|
|
tag "$meta.id"
|
|
label 'process_high'
|
|
|
|
conda (params.enable_conda ? "bioconda::bwa-mem2=2.2.1 bioconda::samtools=1.15" : null)
|
|
container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
|
|
'https://depot.galaxyproject.org/singularity/mulled-v2-e5d375990341c5aef3c9aff74f96f66f65375ef6:8ee25ae85d7a2bacac3e3139db209aff3d605a18-0' :
|
|
'quay.io/biocontainers/mulled-v2-e5d375990341c5aef3c9aff74f96f66f65375ef6:8ee25ae85d7a2bacac3e3139db209aff3d605a18-0' }"
|
|
|
|
input:
|
|
tuple val(meta), path(reads)
|
|
path index
|
|
val sort_bam
|
|
|
|
output:
|
|
tuple val(meta), path("*.bam"), emit: bam
|
|
path "versions.yml" , emit: versions
|
|
|
|
when:
|
|
task.ext.when == null || task.ext.when
|
|
|
|
script:
|
|
def args = task.ext.args ?: ''
|
|
def args2 = task.ext.args2 ?: ''
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
def read_group = meta.read_group ? "-R ${meta.read_group}" : ""
|
|
def samtools_command = sort_bam ? 'sort' : 'view'
|
|
"""
|
|
INDEX=`find -L ./ -name "*.amb" | sed 's/.amb//'`
|
|
|
|
bwa-mem2 \\
|
|
mem \\
|
|
$args \\
|
|
$read_group \\
|
|
-t $task.cpus \\
|
|
\$INDEX \\
|
|
$reads \\
|
|
| samtools $samtools_command $args2 -@ $task.cpus -o ${prefix}.bam -
|
|
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
bwamem2: \$(echo \$(bwa-mem2 version 2>&1) | sed 's/.* //')
|
|
samtools: \$(echo \$(samtools --version 2>&1) | sed 's/^.*samtools //; s/Using.*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
|
|
stub:
|
|
def prefix = task.ext.prefix ?: "${meta.id}"
|
|
"""
|
|
touch ${prefix}.bam
|
|
cat <<-END_VERSIONS > versions.yml
|
|
"${task.process}":
|
|
bwamem2: \$(echo \$(bwa-mem2 version 2>&1) | sed 's/.* //')
|
|
samtools: \$(echo \$(samtools --version 2>&1) | sed 's/^.*samtools //; s/Using.*\$//')
|
|
END_VERSIONS
|
|
"""
|
|
}
|